Shader着色器开发——02光照模型

2021-10-19

字数统计: 3.4k字 | 阅读时长≈ 13分

一、光照模型概念

1、什么是光照模型？

光照模型是一种算法/公式，使用这个公式来计算光照效果（光照到每个点上效果）。

2、一些常用的方法：

normalize() 用来把一个向量，单位化（原来方向保持不变，长度变为1）
max() 用来取得函数中最大的一个
dot 用来取得两个向量的点积
_WorldSpaceLightPos0 取得平行光的位置
_LightColor0 取得平行光的颜色
UNITY_LIGHTMODEL_AMBIENT 用来获取环境光
UNITY_MATRIX_MVP 这个矩阵用来把一个坐标从模型空间转换到剪裁空间（屏幕空间相机锥形空间）
_World2Object 这个矩阵用来把一个方向从世界空间转换到模型空间

二、标准光照模型

在标准光照模型里面，我们把进入摄像机的光分为下面四个部分:

自发光（self-luminous）
漫反射（Diffuse）
高光反射（Specular）
环境光反射（ambient light）

** 01、漫反射 Diffuse**

** Diffuse = 直射光颜色 * cos夹角（光和发现的夹角）（cos夹角的值：1~0） **
Diffuse = 直射光颜色 * max(0,cos夹角(光和法线的夹角) ) （max取最大值负数的话，取值0）cosθ = 光方向· 法线方向

** 光和法线的夹角夹角计算方式划分：**

兰伯特光照模型
- Diffuse = 直射光颜色 * max(0,cos夹角(光和法线的夹角) ) cosθ = 光方向· 法线方向
半兰伯特光照模型
- Diffuse = 直射光颜色 *（ cosθ *0.5 +０.５）（1-0之间的变化）

**
**

02、高光反射 Specular

** 根据夹角不同划分：**

**Blinn光照模型 **
- Specular=直射光 * pow( max(cosθ,0),10) θ:是反射光方向和视野方向的夹角
Blinn-Phong光照模型
Specular=直射光 * pow( max(cosθ,0),10) θ:是法线和x的夹角。 x 是平行光和视野方向的平分线。

**03、环境光反射 **ambient light

Tags{ “LightMode”=”ForwardBase” }

只有定义了正确的LightMode才能得到一些Unity的内置光照变量

#include “Lighting.cginc”

包含unity的内置的文件，才可以使用unity内置的一些变量

三、UnityCG.cginc中一些常用的函数

摄像机方向（视角方向）
- float3 WorldSpaceViewDir(float4 v) 根据模型空间中的顶点坐标得到（世界空间）从这个点到摄像机的观察方向
- float3 UnityWorldSpaceViewDir(float4 v) 世界空间中的顶点坐标==》世界空间从这个点到摄像机的观察方向
- float3 ObjSpaceViewDir(float4 v) 模型空间中的顶点坐标==》模型空间从这个点到摄像机的观察方向
光源方向
- float3 WorldSpaceLightDir(float4 v) 模型空间中的顶点坐标==》世界空间中从这个点到光源的方向
- float3 UnityWorldSpaceLightDir(float4 v) 世界空间中的顶点坐标==》世界空间中从这个点到光源的方向
- float3 ObjSpaceLightDir(float4 v) 模型空间中的顶点坐标==》模型空间中从这个点到光源的方向
方向转换
- float3 UnityObjectToWorldNormal(float3 norm) 把法线方向模型空间==》世界空间
- float3 UnityObjectToWorldDir(float3 dir) 把方向模型空间=》世界空间
- float3 UnityWorldToObjectDir(float3 dir) 把方向世界空间=》模型空间

四、漫反射和高光反射的统一实现（复习）

Shader "LJK/10_testDiffuseSpecularShader"
{
    //Inpector面板显示的属性
    Properties{
        _Diffuse("LJK 默认颜色",Color)=(1,1,1,1)    //默认白色
        _Specular("Specular Color",Color)=(1,1,1,1) //高光反射的颜色
		    _Gloss("Gloss",Range(8,200)) = 10           //高光系数，光滑度
        }
    //漫反射高光复习
    SubShader{
        Pass
        {
            Tags{ "LightMode"="ForwardBase" }//正确定义Tags，取到与光有关的属性 （LightMode）！！！
            CGPROGRAM
        #include "Lighting.cginc" //取得第一个直射光的颜色，_LightColor0(Unity内置的变量)
                                  //取得第一个直射光的位置，_WorldSpaceLightPos0(Unity内置的变量) 
        #include <UnityShaderUtilities.cginc>//引入Unity内置的CG文件
            #pragma vertex vert    //定义顶点函数
            #pragma fragment frag  //定义片元函数

            //重新定义属性变量
            fixed4  _Diffuse;
            fixed4  _Specular;
			      half    _Gloss;


            //定义两个结构体
            //01、给顶点函数传递的结构体（顶点函数的形参（传入参数）类型）--从应用到顶点
            struct a2v{
                //001、获取模型空间下的 顶点位置，完成顶点位置的转换。
                float4 vertex:POSITION;  //获取模型空间下的顶点坐标。POSITION——"模型空间下的顶点坐标"。（POSITION语义：告诉unity把"模型空间下的顶点坐标"赋值给vertex）
                //002、获取模型空间下的 法线
                float3 normal:NORMAL;//获取模型空间下的法线。（NORMA语义：告诉unity把"模型空间下的法线"赋值给normal）
            };
            //02、给片元函数传递的结构体（顶点函数的返回类型）——从顶点到片元
            struct v2f{
                float4 position:SV_POSITION;    //存储剪裁空间下的顶点坐标        SV_POSITION——"剪裁空间下的顶点坐标"。
                float3 worldNormal:TEXCOORD0;   //存储世界法线
                float4 worldVertex:TEXCOORD1;   //存储世界顶点坐标
            };

            //以下两个函数，系统自动调用
            //01、顶点函数(系统给每个顶点调用，返回结构体）（这个结构体是给片元函数传递的结构体)
            v2f vert(a2v v){
                v2f f;
				        f.position = UnityObjectToClipPos(v.vertex);        //世界顶点，从模型空间站换到世间空间转换
                //f.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
                f.worldNormal=UnityObjectToWorldNormal(v.normal);   //世界法线，从模型空间站换到世间空间转换
                f.worldVertex=mul(v.vertex, unity_WorldToObject);   //根据"世界顶点"和"世界法线"，获取新的世界坐标顶点
				return f;
            }
            
            //02、片元函数(系统给屏幕上的每个像素点调用，调用次数会比较多，返回fixed4类型值，是输出到屏幕上的颜色)
            fixed4 frag(v2f f):SV_Target{
                //法线的方向
                fixed3 normal_dir=normalize(f.worldNormal);
                //光照的方向
                //fixed3 light_dir=normalize(_WorldSpaceLightPos0.xyz);//取得直射光的位置（对于每个顶点来说，光的位置就是光的方向，以为光是平行光）
                fixed3 light_dir = normalize( WorldSpaceLightDir(f.worldVertex).xyz );
                //环境光
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;
                //生成——漫反射颜色（根据兰伯特光照模型生成！）
                //fixed3 diffuse = _LightColor0.rgb * max(0, dot(normal_dir, light_dir)*_Diffuse.rgb);
                //生成——漫反射颜色（根据半兰伯特光照模型生成！）
                //使用半兰伯特光照模型
                float half_lambert=dot(normal_dir, light_dir)*0.5+0.5;
                fixed3 diffuse = _LightColor0.rgb *_Diffuse.rgb*half_lambert;//取得漫反射颜色（两个颜色融合，就是两个颜色相乘）

                //反射光方向
                //fixed3 reflectDir=normalize(reflect(-light_dir,normal_dir));
                //视野方向
                //fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-f.worldVertex);
                fixed3 viewDir=normalize(UnityWorldSpaceViewDir(f.worldVertex));
                //平分线方向
                fixed3 halfDir=normalize((viewDir+light_dir)/2);
                //生成——高光（根据Blinn-Phong光照模型生成。获取视野方向与平分线方向的高光）
                fixed3 specular=_LightColor0.rgb* _Specular.rgb*pow(max(dot(normal_dir,halfDir),0),_Gloss);
                
                //总体显示的颜色
                fixed3 tempColor=diffuse+ambient+specular;//颜色叠加是颜色相加
                return fixed4(tempColor,1);
            }
            ENDCG
        }
    }
    Fallback "Specular"//后备方案
}

五、关于纹理贴图介绍

纹理坐标（UV坐标）

“UV”这里是指u,v纹理贴图坐标的简称(它和空间模型的X, Y, Z轴是类似的). 它定义了图片上每个点的位置的信息. 这些点与3D模型是相互联系的, 以决定表面纹理贴图的位置.

UV就是将图像上每一个点精确对应到模型物体的表面. 在点与点之间的间隙位置由软件进行图像光滑插值处理. 这就是所谓的UV贴图.

** 为什么用UV坐标而不是标准的投影坐标呢?**

通常给物体纹理贴图最标准的方法就是以planar(平面),cylindrical(圆柱), spherical(球形),cubic(方盒)坐标方式投影贴图. Planar projection(平面投影方式)是将图像沿x,y或z轴直接投影到物体. 这种方法使用于纸张, 布告, 书的封面等 - 也就是表面平整的物体.

平面投影的缺点是如果表面不平整, 或者物体边缘弯曲, 就会产生如图A的不理想接缝和变形.

避免这种情况需要创建带有alpha通道的图像, 来掩盖临近的平面投影接缝, 而这会是非常烦琐的工作. 所以不要对有较大厚度的物体和不平整的表面运用平面投影方式. 对于立方体可以在x, y方向分别进行平面投影, 但是要注意边缘接缝的融合. 或者采用无缝连续的纹理, 并使用cubic投影方式. 多数软件有图片自动缩放功能, 使图像与表面吻合. 显然, 如果你的图像与表面形状不同, 自动缩放就会改变图像的比例以吻合表面. 这通常会产生不理想的效果, 所以制作贴图前先测量你的物体尺寸.

** 使用纹理目的：**

利用纹理颜色代替漫反射颜色。

Tiling重复属性（瓷砖平铺）
Offset偏移量

** shader中的各种空间坐标**

http://blog.csdn.net/lyh916/article/details/50906272

常用的Shader收集/整理

关于凹凸映射和法线映射的介绍

HeightMap

NormalMap

Occlusion

Emission

DetailMask

01、使用法线映射和没有使用的对比

法线映射

pixel = (normal+1)/2 normal与pixel的转换关系

normal = pixel*2 - 1

02、什么是切线空间？

http://blog.csdn.net/bonchoix/article/details/8619624

Shader "LJK/14_testRockAlphaShader"
{
    //属性
    Properties{
        
        //_Diffuse("LJK 默认颜色",Color)=(1,1,1,1)    //默认白色
        _Color("纹理颜色",Color)=(0.5,0,0,1)
        _MainTexture("自定义漫反射主贴图",2D)="white"{}
        _NormalMap("法线贴图",2D)="bump"{}  //使用的是切线空间
        _BumpScale("凹凸参数",Float)=1
        _GOAlpha("透明度",Float)=1
    }
    //漫反射高光复习
    SubShader{
        Tags{"Queue"="Transparent" "IngnoreProjector"="True" "RenderType"="Transparent"}
        Pass
        {
            Tags{ "LightMode"="ForwardBase" }//正确定义Tags，取到与光有关的属性 （LightMode）！！！
            ZWrite Off//深度写入关闭
            Blend SrcAlpha OneMinusSrcAlpha
            CGPROGRAM
        #include "Lighting.cginc" //取得第一个直射光的颜色，_LightColor0(Unity内置的变量)
                                  //取得第一个直射光的位置，_WorldSpaceLightPos0(Unity内置的变量) 
        #include <UnityShaderUtilities.cginc>//引入Unity内置的CG文件
            #pragma vertex vert    //定义顶点函数
            #pragma fragment frag  //定义片元函数

            //重新定义属性变量
          //fixed4     _Diffuse;
            fixed4     _Color;
            sampler2D  _MainTexture;
            float4     _MainTexture_ST;//(缩放/偏移)(_ST固定格式后缀)(offset: _ST.zw, tiling: ST.xy)
            sampler2D  _NormalMap;
            float4     _NormalMap_ST;//(缩放/偏移)(_ST固定格式后缀)
            float      _BumpScale;
            float      _GOAlpha;

            //定义两个结构体
            //01、给顶点函数传递的结构体（顶点函数的形参（传入参数）类型）--从应用到顶点
            struct a2v{
                //001、获取模型空间下的 顶点位置，完成顶点位置的转换。
                float4 vertex:POSITION;  //获取模型空间下的顶点坐标。POSITION——"模型空间下的顶点坐标"。（POSITION语义：告诉unity把"模型空间下的顶点坐标"赋值给vertex）
                //002、获取模型空间下的 法线
                float3 normal:NORMAL;//获取模型空间下的法线。（NORMA语义：告诉unity把"模型空间下的法线"赋值给normal）
                //003、获取纹理坐标
                float4 texcoord:TEXCOORD0;

                //004、确定切线空间中坐标轴的方向的（定义之后，TANGENT_SPACE_ROTATION可以用）
                float4 tangent:TANGENT;         //tangent.w是用来确定切线空间中坐标轴的方向的
            };
            //02、给片元函数传递的结构体（顶点函数的返回类型）——从顶点到片元
            struct v2f{
                float4 position:SV_POSITION;    //存储剪裁空间下的顶点坐标        SV_POSITION——"剪裁空间下的顶点坐标"。
                float3 light_Dir:TEXCOORD0;     //切线空间下平行光的方向
                float4 uv:TEXCOORD2;            //存储uv坐标(xy用来存储MainTexture的纹理坐标，zw用来存储NormalMap的纹理坐标)
            };

            //以下两个函数，系统自动调用
            //01、顶点函数(系统给每个顶点调用，返回结构体）（这个结构体是给片元函数传递的结构体)
            v2f vert(a2v v){
                v2f f;
				f.position = UnityObjectToClipPos(v.vertex);        //世界顶点，从模型空间站换到世间空间转换
                f.uv.xy= v.texcoord.xy*_MainTexture_ST.xy + _MainTexture_ST.zw;
                f.uv.zw= v.texcoord.xy*_NormalMap_ST.xy+_NormalMap_ST.zw;

                TANGENT_SPACE_ROTATION;//调用这个宏之后，会得到一个矩阵，rotation这个矩阵用来把模型空间下的方向转换成切线空间下
                //ObjSpaceLightDir(v.vertex);//得到模型空间下的平行光方向
                f.light_Dir=mul(rotation,ObjSpaceLightDir(v.vertex));
				return f;
            }
            //把所有根法线方向有关的运算都放在切线空间下
            //从法线贴图里面取得的法线方向是在切线空间下的  ---"切线和法线是垂直的"---
            //02、片元函数(系统给屏幕上的每个像素点调用，调用次数会比较多，返回fixed4类型值，是输出到屏幕上的颜色)
            fixed4 frag(v2f f):SV_Target{
                //法线的方向
                //fixed3 normal_dir=normalize(f.worldNormal);
                //根据颜色值获取法线
                fixed4 normalColor=tex2D(_NormalMap,f.uv.zw);//得到像素值
                //获取法线的方向(切线空间下)
                fixed3 tangentNormalDir=UnpackNormal(normalColor);//正确读取法线的方式
                tangentNormalDir.xy=tangentNormalDir.xy*_BumpScale;//控制法线xy力度
                //获取光照的方向
                fixed3 lightDir =normalize(f.light_Dir);
                //环境光
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb;
                //生成——漫反射颜色（根据半兰伯特光照模型生成！）
                //使用半兰伯特光照模型
                float half_lambert=dot(tangentNormalDir, lightDir)*0.5+0.5;
                //取得纹理坐标对应的图片颜色
                fixed4 texColor=tex2D(_MainTexture,f.uv.xy)*_Color;
                fixed3 diffuse = _LightColor0.rgb *texColor.rgb*half_lambert;//取得漫反射颜色（两个颜色融合，就是两个颜色相乘）
                //总体显示的颜色
                fixed3 tempColor=diffuse+ambient*texColor;//颜色叠加是颜色相加
                // return fixed4(tempColor,_GOAlpha);
                //return fixed4(tempColor,texColor.a);
                return fixed4(tempColor,_GOAlpha*texColor.a);
            }
            ENDCG
        }
    }
    Fallback "Specular"//后备方案
}

本文作者： 梁俊可
本文链接： http://ljk3d.com/2021/10/19/unityNote/UnityBasic/Shader着色器开发——02光照模型/
版权声明： 梁俊可工作室

一、光照模型概念

二、标准光照模型

三、UnityCG.cginc中一些常用的函数

四、漫反射和高光反射的统一实现（复习）

五、关于纹理贴图介绍